; rst vectors

SECTION "rst0", ROM0[0]
	di
	ld [hCrashSavedA], a
	ld a, $0 ; because xor a destroys f
	jp Crash

SECTION "rst8", ROM0[FarCall]
	jp StackFarCall

DrawBattleHPBar::
; Draw an HP bar d tiles long at hl
; Fill it up to e pixels
	jpba _DrawBattleHPBar

GenericDummyString:
	db "@"

SECTION "rst10", ROM0[GenericBankswitch]
	jp _GenericBankswitch

IsAPokemon::
; Return carry if species a is not a Pokemon.
; since every ID other than $00 and $ff is valid, we can simplify this function
	inc a
	cp 2
	dec a
	ret

SECTION "rst18", ROM0[AddNTimes]
	jp _AddNTimes

GetFarByteAndIncrement::
	call GetFarByte
	inc hl
GenericDummyFunction:: ;keeping this here since it's easy to find
	ret

SECTION "rst20", ROM0[Predef]
	jp _Predef

BattleCommand_MoveDelay:
; movedelay
; Wait 40 frames.
	ld c, 40
	jp DelayFrames

SECTION "rst28", ROM0[JumpTable]
	jp Jumptable

LoadStandardFont::
	jpba _LoadStandardFont

GenericDummyScript::
	end

SECTION "rst30", ROM0[CopyBytes]
	jp _CopyBytes

SetEnemyTurn::
	ld a, 1
	ld [hBattleTurn], a
	ret

SECTION "rst38", ROM0[$38]
; debugging purposes
	di
	ld [hCrashSavedA], a
	ld a, $1
	jp Crash
